**Linked Economy Ontology Cookbook**

Πίνακας περιεχομένων

[Πρόλογος 3](#_Toc435789531)

[ΚΗΜΔΗΣ 4](#_Toc435789532)

[Κλάσεις (Classes) 4](#_Toc435789533)

[FOAF 4](#_Toc435789534)

[Public Contracts 4](#_Toc435789535)

[Good Relations 4](#_Toc435789536)

[Organization 4](#_Toc435789537)

[SKOS 4](#_Toc435789538)

[Registered Organization 5](#_Toc435789539)

[vCard 5](#_Toc435789540)

[Linked Economy 5](#_Toc435789541)

[Linked Economy Geo 5](#_Toc435789542)

[Ιδιότητες Αντικειμένων (Object Properties) 5](#_Toc435789543)

[Public Contracts 5](#_Toc435789544)

[Good Relations 6](#_Toc435789545)

[Organization 6](#_Toc435789546)

[SKOS 6](#_Toc435789547)

[vCard 7](#_Toc435789548)

[Linked Economy 7](#_Toc435789549)

[Ιδιότητες Τύπου Δεδομένων (Datatype Properties) 8](#_Toc435789550)

[FOAF 8](#_Toc435789551)

[Public Contracts 8](#_Toc435789552)

[Good Relations 8](#_Toc435789553)

[SKOS 9](#_Toc435789554)

[vCard 9](#_Toc435789555)

[Dublin Core Terms 9](#_Toc435789556)

[Linked Economy 9](#_Toc435789557)

[Ερωτήματα & Αποτελέσματα (SPARQL Queries) 9](#_Toc435789558)

[Στοιχεία Πληρωμής 9](#_Toc435789559)

[Άθροισμα και πλήθος Πληρωμών Φορέα του έτους 2014 10](#_Toc435789560)

[Άθροισμα Συμβολαίων Αναδόχου του έτους 2014 11](#_Toc435789561)

[Φορείς ταξινομημένοι κατά συνολικό ποσό των Πληρωμών του έτους 2014 11](#_Toc435789562)

[Ανάδοχοι ταξινομημένοι κατά συνολικό ποσό των Συμβολαίων του έτους 2014 12](#_Toc435789563)

[Συνδυασμός Πηγών 14](#_Toc435789564)

[Ερωτήματα & Αποτελέσματα (SPARQL Queries) 14](#_Toc435789565)

[Ανάδοχοι με συναλλαγές στη Διαύγεια, στο ΚΗΜΔΗΣ και στο ΕΣΠΑ 14](#_Toc435789566)

[Πλήθος συναλλαγών Αναδόχου στη Διαύγεια, ΚΗΜΔΗΣ και ΕΣΠΑ 14](#_Toc435789567)

[Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Οριστικοποίησης Πληρωμών (Β.2.2) του έτους 2015 15](#_Toc435789568)

[Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Πληρωμών ΕΣΠΑ 16](#_Toc435789569)

[Στοιχεία Πληρωμής και Αντικειμένου Εισηγμένης ως Ανάδοχος στο ΚΗΜΔΗΣ 18](#_Toc435789570)

# Πρόλογος

Σε αυτό το έγγραφο παρουσιάζεται η Οντολογία του LinkedEconomy η οποία προτείνεται για τη μοντελοποίηση της εκάστοτε πηγής. Παρουσιάζονται και περιγράφονται οι Κλάσεις, οι Ιδιότητες Αντικειμένων και οι Ιδιότητες Τύπου Δεδομένων των οντολογιών καθώς και παραδείγματα SPARQL ερωτημάτων με ένα δείγμα απαντήσεών τους. Κατά την αναπαράσταση των κλάσεων και των ιδιοτήτων χρησιμοποιούνται κάποια συγκεκριμένα namespaces και prefixes τα οποία παρουσιάζονται στον Πίνακα 1 μαζί με την οντολογία ή το λεξικό στο οποίο αντιστοιχούν.

|  |  |  |
| --- | --- | --- |
| Prefix | URI | Ontology / Vocabulary |
| rdf | http://www.w3.org/1999/02/22-rdf-syntax-ns# | RDF |
| rdfs | http://www.w3.org/2000/01/rdf-schema# | RDFS |
| xsd | http://www.w3.org/2001/XMLSchema# | XSD |
| gr | http://purl.org/goodrelations/v1# | Good Relations |
| pc | http://purl.org/procurement/public-contracts# | Public Contracts |
| foaf | http://xmlns.com/foaf/0.1/# | FOAF |
| org | http://www.w3.org/ns/org# | Organization |
| rov | http://www.w3.org/ns/regorg# | Registered Organization |
| dc | http://purl.org/dc/elements/1.1/ | Dublin Core |
| dcterms | http://purl.org/dc/terms/ | Dublin Core Terms |
| skos | http://www.w3.org/2004/02/skos/core# | SKOS |
| vCard | http://www.w3.org/2006/vcard/ns# | vCard |
| dbo | http://dbpedia.org/ontology/ | DBpedia |
| elod | http://linkedeconomy.org/ontology# | Linked Economy |
| elodGeo | http://linkedeconomy.org/geoOntology# | Linked Economy Geo |

Πίνακας 1: Τα prefixes και οι οντολογίες/λεξιλόγια στις οποίες ανήκουν

# ΚΗΜΔΗΣ

## Κλάσεις (Classes)

### FOAF

* foaf:Agent: Αυτή η κλάση αναπαριστά τις οντότητες οι οποίες συμμετέχουν σε δράσεις.
* foaf:Organization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.
* foaf:Person: Αυτή η κλάση αναπαριστά φυσικά πρόσωπα.

### Public Contracts

* pc:Contract: Αυτή η κλάση αναπαριστά τις δημόσιες συμβάσεις σε όλα τα στάδια της ύπαρξής τους.
* pc:CriterionWeighting: Αυτή η κλάση αναπαριστά τα κριτήρια ανάθεσης μιας δημόσιας σύμβασης.
* pc:AwardCriteriaCombination: Αυτή η κλάση αναπαριστά τα κριτήρια τα οποία καθορίζουν τους όρους υπό τους οποίους θα επιλεχθεί και θα κατακυρωθεί η καλύτερη προσφορά.
* gr:TypeAndQuantityNode: Η κατηγορία αυτή περιλαμβάνει όλη την πληροφορία για ένα προϊόν, όπως το είδος του προϊόντος, την ποσότητά του καθώς και την μονάδα μέτρησής του.

### Good Relations

* gr:BusinessEntity: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.
* gr:UnitPriceSpecification: Αυτή η κλάση αντιπροσωπεύει μια εννοιολογική οντότητα που καθορίζει την τιμή που ζητείται για μια υπηρεσία ή ένα προϊόν. Προσδιορίζει την τιμή, το νόμισμα και εάν η τιμή περιλαμβάνει ΦΠΑ ή όχι.
* gr:Offering: Αυτή η κλάση περιέχει στιγμιότυπα της pc:TypeAndQuantitiveRole καθώς και τον ανάδοχο μίας υπηρεσίας ή ενός προϊόντος.
* gr:SomeItems: Αυτή η κλάση περιλαμβάνει τις πληροφορίες μίας υπηρεσίας ή ενός προϊόντος.

### Organization

* org:Organization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.
* org:OrganizationalUnit: Αυτή η κλάση αναπαριστά τις οργανωτικές μονάδες των φορέων.
* org:Role: Αυτή η κλάση αναπαριστά το ρόλο που παίζει ο πράκτορας και τη σχέση με έναν οργανισμό.
* org:Membership: Αυτή η κλάση αντιπροσωπεύει τη συσχέτιση μεταξύ ενός πράκτορα, ενός οργανισμού και κάποιου ρόλου.

### SKOS

* skos:Concept: Αυτή η κλάση αντιπροσωπεύει τις μονάδες σκέψης - ιδέες, έννοιες, ή (κατηγορίες) αντικειμένων και γεγονότων - τα οποία κρύβονται πίσω από πολλά συστήματα οργάνωσης γνώσης.
* skos:ConceptScheme: Αυτή η κλάση αποτελεί μια συλλογή από skos:Concept ως μέσο αναπαράστασης γνώσης.

### Registered Organization

* rov:RegisteredOrganization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### vCard

* vcard2006:Address: Αυτή η κλάση αναπαριστά τα στοιχεία της διεύθυνσης ενός πράκτορα.

### Linked Economy

* elod:SpendingItem: Αυτή η κλάση αναπαριστά τις πληρωμές.
* elod:ExpenditureLine: Αυτή η κλάση αναπαριστά αποφάσεις που περιλαμβάνουν δαπάνες.
* elod:Currency: Αυτή η κλάση αναπαριστά τα νομίσματα.
* elod:CPV: Αυτή η κλάση αναπαριστά τους κωδικούς CPV. Είναι ένα λεξιλόγιο το οποίο χρησιμοποιείται για να χαρακτηρίσει τα προϊόντα ή τις υπηρεσίες που αγοράζονται από σύμβαση.
* elod:Decision: Αυτή η κλάση αναπαριστά αποφάσεις οι οποίες έχουν τύπου άλλου πέραν του B.1.3, B.2.1, B.2.2, Δ.1, Δ.2.1, Δ.2.2.
* elod:CorrectionDecision: Αυτή η κλάση αναπαριστά ένα στιγμιότυπο της elod:Decision της οποίας ο ρόλος είναι να ακυρώσει μία δημόσια σύμβαση.
* elod:VatType: Αυτή η κλάση αναπαριστά τους τύπους ΑΦΜ των πρακτόρων.
* elod:SelectionCriterion: Αυτή η κλάση αναπαριστά τα κριτήρια για τα οποία έχει επιλεγεί μια σύμβαση.
* elod:Vat: Αυτή η κλάση παρουσιάζει τα ποσοστά του ΦΠΑ που συνοδεύουν τα ποσά.
* elod:ContractType: Αυτή η κλάση αναπαριστά τον τύπο μίας δημόσιας προμήθειας.

### Linked Economy Geo

* elodGeo:Country: Αυτή η κλάση αναπαριστά τις χώρες.

## Ιδιότητες Αντικειμένων (Object Properties)

### Public Contracts

* pc:awardCriteriaCombination: Αυτή η ιδιότητα συσχετίζει ένα σύνολο κριτηρίων με μια δημόσια σύμβαση.
* pc:awardCriterion: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:AwardCriteriaCombination με ένα σταθμισμένο κριτήριο το οποίο είναι στιγμιότυπο της (pc:CriterionWeighting).
* pc:weightedCriterion: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:CriterionWeighting με το είδος του κριτηρίου.
* pc:documentsPrice: Μία δημόσια σύμβαση έχει συνήθως μια εκτιμώμενη τιμή η οποία καθορίζεται πριν από την παραλαβή των προσφορών. Μπορεί να είναι μια ακριβής εκτιμώμενη τιμή ή ένα εύρος που να περιλαμβάνει ελάχιστη και μέγιστη εκτιμώμενη τιμή. Και στις δύο περιπτώσεις, η τιμή συνδέεται με τη σύμβαση μέσω αυτής της ιδιότητας.
* pc:actualPrice: Η ιδιότητα αυτή συνδέει την πραγματική τιμή μίας δημόσιας σύμβασης αφού έχει πραγματοποιηθεί με ενός συμβολαίου.
* pc:agreedPrice: Μετά την έγκριση μιας σύμβαση, μία τιμή συμφωνείται μεταξύ του προμηθευτή και της αναθέτουσας αρχής. Αυτή η ιδιότητα ορίζει αυτήν την τιμή στο συμβόλαιο.
* pc:procedureType: Αυτή η ιδιότητα καθορίζει τη διαδικασία η οποία καθορίζει τον τρόπο με τον οποίο δημοσιεύονται πληροφορίες σχετικά με μια σύμβαση καθώς και με τον τρόπο με τον οποίο επιλέγεται ένας προμηθευτής.
* pc:kind: Αυτή η ιδιότητα καθορίζει τη βασική εστίαση μίας δημόσιας σύμβασης.
* pc:item: Η ιδιότητα αυτή συσχετίζει ένα στιγμιότυπο της pc:Contract με ένα της gr:Offering.

### Good Relations

* gr:hasPriceSpecification: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της gr:Offering με ένα της gr:UnitPriceSpecification.
* gr:includesObject: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της gr:Offering με μηδέν η περισσότερα της gr:SomeItems.
* gr:typeOfGood: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:TypeAndQuantityNode με ένα της gr:SomeItems.

### Organization

* org:role: Αυτή η ιδιότητα καθορίζει το ρόλο που έχει ένας πράκτορας σε έναν οργανισμό.
* org:hasMember: Αυτή η ιδιότητα καθορίζει έναν πράκτορα ο οποίο ανήκει σε έναν οργανισμό.
* org:member: Αυτή η ιδιότητα καθορίζει έναν πράκτορας ο οποίο συμμετέχει σε μία σχέση μέλους.
* org:organization: Αυτή η ιδιότητα καθορίζει τον οργανισμό στον οποίο ένας πράκτορας είναι μέλος.

### SKOS

* skos:hasTopConcept: Αυτή η ιδιότητα χρησιμοποιείται για τη σύνδεση ενός SKOS Concept Scheme SKOS Concepts τα οποία είναι πρώτα στη λίστα των ιεραρχικών σχέσεων του εν λόγω Scheme.
* skos:inScheme: Αυτή η ιδιότητα χρησιμοποιείται για να εκφραστεί ότι ένα SKOS Concept συμμετέχει σε ένα Concept Scheme.
* skos:topConceptOf: Αυτή η ιδιότητα είναι η αντίστροφη της skos:hasTopConcept.
* skos:broader: Αυτή η ιδιότητα παρέχει μία ιεραρχική σχέση μεταξύ των δύο SKOS Concepts και δείχνει ότι το ένα είναι κατά κάποιο τρόπο πιο γενικό («broader») από το άλλο («narrower»).
* skos:narrower: Αυτή η ιδιότητα παρέχει μία ιεραρχική σχέση μεταξύ των δύο SKOS Concepts και δείχνει ότι το ένα είναι κατά κάποιο τρόπο πιο συγκεκριμένο («narrower») από το άλλο («broader»).

### vCard

* vcard2006:hasAddress: Αυτή η ιδιότητα συσχετίζει οντότητες με στιγμιότυπα της vcard2006:Address η οποία περιέχει πληροφορίες διεύθυνσης

### Linked Economy

* elod:hasCurrency: Αυτή η ιδιότητα καθορίζει το νόμισμα για τα ποσά που ορίζονται από το gr:UnitPriceSpecification.
* elod:amount: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της gr:UnitPriceSpecification με ένα της elod:ExpenditureLine.
* elod:hasExpenditureLine: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της elod:SpendingItem με ένα της elod:ExpenditureLine.
* elod:hasRelatedContract: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της elod:CommittedItem, της elod:ExpenseApprovalItem ή της a pc:Contract με ένα της pc:Contract.
* elod:hasCorrectedDecision: Αυτή η ιδιότητα συσχετίζει μία οπουδήποτε είδους απόφαση με μία ίδιου τύπου. Χρησιμοποιείται για να ακυρώσει τη συγκεκριμένη δημόσια σύμβαση.
* elod:isRegisteredAt: Αυτή η ιδιότητα συσχετίζει έναν πράκτορα με τη χώρα στην οποία έχει καταχωρηθεί.
* elod:signer: Η ιδιότητα αυτή συνδέει μια απόφαση με τον υπογράφοντά της.
* elod:hasVatType: Αυτή η ιδιότητα συσχετίζει έναν πράκτορα με ένα SKOS Concept το οποίο αντιπροσωπεύει την κατηγορία του ΑΦΜ του.
* elod:buyer: Αυτή η ιδιότητα συσχετίζει έναν οργανισμό ή μία οργανωτική μονάδα με μία απόφαση. Πρόκειται για τον Φορέα της απόφασης.
* elod:seller: Αυτή η ιδιότητα συσχετίζει έναν οργανισμό, μία οργανωτική μονάδα ή ένα φυσικό πρόσωπο με μία απόφαση. Πρόκειται για τον Ανάδοχο της απόφασης.
* elod:hasCurrency: Αυτή η ιδιότητα καθορίζει το νόμισμα για τις τιμές που εμφανίζονται στα στιγμιότυπα της gr:UnitPriceSpecification.
* elod:hasCPV: Οι συμβάσεις που σχετίζονται με τους κωδικούς CPV. Αυτή η ιδιότητα τους συνδέει με στιγμιότυπα των κλάσεων πέραν των pc:Contracts.
* elod:hasVat: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της gr: UnitPriceSpecification με ένα της elod:Vat.
* elod:productCategory: Κάθε προϊόν ή υπηρεσία συνδέεται με έναν κωδικό CPV. Αυτή η ιδιότητα τους σχετίζεται με ένα στιγμιότυπο της gr:Offering.
* elod:producedAt: Αυτή η ιδιότητα συσχετίζει ένα SKOS Concept το οποίο αναπαριστά τη χώρα στην οποία έχει κατασκευαστεί ένα προϊόν με ένα στιγμιότυπο της gr:SomeItems.
* elod:deliveryLocation: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της vcard2006:Address με ένα της pc:TypeAndQuantitiveNode.
* elod:hasRevokedDecision: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της elod:CorrectionDecision με ένα της pc:Contract. Χρησιμοποιείται για να καθορίσει την απόφαση η οποία ακυρώνει τη συγκεκριμένη σύμβαση.
* elod:cancellationReason: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:Contract με το λόγο της ακύρωσης του.
* elod:hasContractType: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:Contract με ένα SKOS Concept το οποίο αναπαριστά τον τύπο της σύμβασης.
* elod:country: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της vcard2006:Address με ένα της elodGeo:Country.
* elod:contractConcernsTender: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:Contract με ένα της pc:Contract. Χρησιμοποιείται για να συσχετίσει μία δημόσια σύμβαση από τη φάση της «προμήθειας» στη φάση της «σύμβασης».
* elod:contractExtendsContract: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:Contract με ένα της pc:Contract. Χρησιμοποιείται για να επεκτείνει μία δημόσια σύμβαση από τη φάση της «σύμβασης».
* elod:contractChangesContract: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:Contract με ένα της pc:Contract. Χρησιμοποιείται για να αλλάξει μία δημόσια σύμβαση από τη φάση της «σύμβασης».
* elod:paymentConcernsContract: Αυτή η ιδιότητα συσχετίζει ένα στιγμιότυπο της pc:Contract με ένα της pc:Contract. Χρησιμοποιείται για να συσχετίσει μία δημόσια σύμβαση από τη φάση της «σύμβασης» με μία από τη φάση της «πληρωμής».

## Ιδιότητες Τύπου Δεδομένων (Datatype Properties)

### FOAF

* foaf:firstName: Το μικρό όνομα ενός στιγμιοτύπου της κλάσης foaf:Person.
* foaf:lastName: Το επίθετο ενός στιγμιοτύπου της κλάσης foaf:Person.

### Public Contracts

* pc:criterionWeight: Το βάρος που αποδίδεται για ένα συγκεκριμένο κριτήριο.
* pc:startDate: Η ημερομηνία έναρξης μίας δημόσιας σύμβασης.
* pc:estimatedEndDate: Η εκτιμώμενη ημερομηνία έναρξης μίας δημόσιας σύμβασης.
* pc:tenderDeadline: Η καταληκτική ημερομηνία των προσφορών των προμηθειών μίας δημόσιας σύμβασης.

### Good Relations

* gr:name: Το όνομα ενός στιγμιοτύπου της foaf:Agent όπως καταχωρήθηκε στην πηγή. Μπορεί να συνοδεύεται απ ένδειξη γλώσσας.
* gr:vatID: Ο ΑΦΜ ενός στιγμιοτύπου της foaf:Agent.
* gr:legalName: Η επίσημη ονομασία ενός στιγμιοτύπου της foaf:Agent. Μπορεί να συνοδεύεται με ένδειξη γλώσσα.
* gr:hasCurrencyValue: Το ποσό των χρημάτων που καθορίζεται σε ένα στιγμιότυπο της gr:UnitPriceSpecification.
* gr:valueAddedTaxIncluded: Υποδεικνύει εάν ο ΦΠΑ περιλαμβάνεται στην τιμή που καθορίζεται ή όχι.
* gr:description: Η περιγραφή του παρέχεται για μια υπηρεσία ή ένα προϊόν.
* gr:amountOfThisGood: Η ζητούμενη ποσότητα για μία υπηρεσία ή ένα προϊόν.
* gr:hasUnitOfMeasurement: Η μονάδα μέτρησης για μια υπηρεσία ή ένα προϊόν χρησιμοποιώντας τον UN/CEFACT Common Code (3 χαρακτήρες).

### SKOS

* skos:prefLabel: Αυτή η ιδιότητα παρέχει την προτιμώμενη λεξικολογική ετικέτα για έναν πόρο, σε μια δεδομένη γλώσσα.

### vCard

* vcard2006:street-address: Το όνομα του δρόμου και ο αριθμός της διεύθυνσης.
* vcard2006:locality : Η περιοχή της περιγραφείσας διεύθυνσης.
* vcard2006:country-name : ο όνομα της χώρας της περιγραφείσας διεύθυνσης.
* vcard2006:postal-code : Ο ταχυδρομικός κώδικας της περιγραφείσας διεύθυνσης.

### Dublin Core Terms

* dcterms:issued: Η ημερομηνία έκδοσης μίας απόφασης.
* dcterms:title: Ο τίτλος μίας δημόσιας σύμβασης

### Linked Economy

* elod:countryIsoCode: Ο κωδικός δύο γραμμάτων της χώρας εκφρασμένος στη μορφή ISO 3166-1 alpha-2.
* elod:currencyIsoCode: Ο κωδικός τριών γραμμάτων του νομίσματος εκφρασμένος στη μορφή ISO 4217.
* elod:protocolNumber: Ο αριθμός πρωτοκόλλου της απόφασης.
* elod:submissionTimestamp: Η ημερομηνία κατά την οποία η απόφαση εισήχθη στο σύστημα.
* elod:validVatId: Υποδεικνύει εάν το ΑΦΜ ενός πράκτορα είναι έγκυρο ή όχι.
* elod:authorEmail: Η διεύθυνση ηλεκτρονικού ταχυδρομείου ενός χρήστη.
* elod:contractId: Το μοναδικό αναγνωριστικό της δημόσιας σύμβασης (ΑΔΑΜ).
* elod:signatureDate: Η ημερομηνία υπογραφής της δημόσιας σύμβασης.
* elod:contractNumber: Ο αριθμός της δημόσιας σύμβασης.
* elod:vatPercentage: Η πραγματική τιμή του ποσοστού ΦΠΑ.
* elod:amountPerUnit: Το κόστος ανά μονάδα υπηρεσίας ή προϊόντος.

## Ερωτήματα & Αποτελέσματα (SPARQL Queries)

### Στοιχεία Πληρωμής

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX dcterms: <http://purl.org/dc/terms#>

SELECT ?adam ?title ?signatureDate ?buyer ?buyerLegalName ?seller ?sellerLegalName (xsd:decimal(?amount) AS ?paymentAmount) ?vat (xsd:decimal((1+?vat/100)\*?amount) AS ?paymentAmountInclVat) (SAMPLE(?cpv) AS ?cpv)

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Organizations>

WHERE {

<http://linkedeconomy.org/resource/SpendingItem/13PAY001671899> elod:hasExpenditureLine ?expLine ;

elod:hasRelatedContract ?relatedContract ;

elod:buyer ?buyer .

#expLine

?expLine elod:seller ?seller ;

elod:amount ?ups ;

elod:hasCpv ?cpv .

#ups

?ups gr:hasCurrencyValue ?amount ;

elod:hasVat ?vatRes .

?buyer gr:legalName ?buyerLegalName .

?seller gr:legalName ?sellerLegalName .

?vatRes elod:vatPercentage ?vat .

#relatedContract

?relatedContract elod:signatureDate ?signatureDate ;

elod:contractId ?adam ;

dcterms:title ?title .

FILTER(LANG(?buyerLegalName) = "") .

FILTER NOT EXISTS {?correctedDec elod:hasCorrectedDecision ?relatedContract} .

}

Αποτελέσματα ερωτήματος

|  |  |
| --- | --- |
| **Όνομα Πεδίου** | **Τιμή** |
| **ΑΔΑΜ** | 13PAY001671899 |
| **Τίτλος** | Ασφάλιση οχηματων και μηχανημάτων |
| **Ημ/νια Υπογραφής** | 2013-10-14+03:00 |
| **Φορέας** | http://linkedeconomy.org/resource/Organization/998895715/6137 |
| **Όνομα Φορέα** | ΔΗΜΟΣ ΚΑΡΠΕΝΗΣΙΟΥ |
| **Ανάδοχος** | <http://linkedeconomy.org/resource/Organization/094047601> |
| **Όνομα Αναδόχου** | ΥΔΡΟΓΕΙΟΣ ΑΝΩΝΥΜΟΣ ΑΣΦΑΛΙΣΤΙΚΗ ΚΑΙ ΑΝΤΑΣΦΑΛΙΣΤΙΚΗ ΕΤΑΙΡΕΙΑ ||ΥΔΡΟΓΕΙΟΣ ΑΑ ΚΑΙ ΑΕ |
| **Ποσό Πληρωμής** | 2191392512 |
| **ΦΠΑ** | 23.0 |
| **Ποσό με ΦΠΑ** | 2695412736 |
| **CPV** | <http://linkedeconomy.org/resource/CPV/31211300-1> |

### Άθροισμα και πλήθος Πληρωμών Φορέα του έτους 2014

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT (SUM(xsd:decimal(?amount)) AS ?totalAmount) (COUNT(?contract) AS ?totalPayments)

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Organization>

WHERE {

?contract elod:buyer <http://linkedeconomy.org/resource/Organization/090208606/99206226> ;

pc:actualPrice ?ups ;

elod:submissionTimestamp ?submissionTimestamp .

?ups gr:hasCurrencyValue ?amount .

FILTER NOT EXISTS {?correctedDec elod:hasCorrectedDecision ?contract } .

FILTER (?submissionTimestamp >= "2014-01-01T00:00:00Z"^^xsd:dateTime) .

FILTER (?submissionTimestamp < "2015-01-01T00:00:00Z"^^xsd:dateTime) .

}

Αποτελέσματα ερωτήματος

|  |  |
| --- | --- |
| **Συνολικό Ποσό** | **Αριθμός Πληρωμών** |
| 424498395726.017578 | 44 |

### Άθροισμα Συμβολαίων Αναδόχου του έτους 2014

PREFIX pc: <http://purl.org/procurement/public-contracts#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX gr: <http://purl.org/goodrelations/v1#>

SELECT (SUM(xsd:decimal(?amount)) AS ?paymentAmount) (COUNT(?contract) AS ?contractCounter)

FROM <http://linkedeconomy.org/EprocurementProper>

WHERE {

?contract pc:agreedPrice ?ups ;

elod:seller <http://linkedeconomy.org/resource/Organization/094006030> ;

elod:submissionTimestamp ?submissionTimestamp .

?ups gr:hasCurrencyValue ?amount .

FILTER NOT EXISTS {?correctedDec elod:hasCorrectedDecision ?contract } .

FILTER (?submissionTimestamp >= "2014-01-01T00:00:00Z"^^xsd:dateTime) .

FILTER (?submissionTimestamp < "2015-01-01T00:00:00Z"^^xsd:dateTime) .

}

Αποτελέσματα ερωτήματος

|  |  |
| --- | --- |
| **Συνολικό Ποσό** | **Αριθμός Συμβολαίων** |
| 112355051.5625 | 5 |

### Φορείς ταξινομημένοι κατά συνολικό ποσό των Πληρωμών του έτους 2014

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT ?buyer (SUM(xsd:decimal(?amount)) AS ?totalAmount) (COUNT(?contract) AS ?totalPayments)

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Organization>

WHERE {

?contract elod:buyer ?buyer ;

pc:actualPrice ?ups ;

elod:submissionTimestamp ?submissionTimestamp .

?ups gr:hasCurrencyValue ?amount .

FILTER NOT EXISTS {?correctedDec elod:hasCorrectedDecision ?contract } .

FILTER (?submissionTimestamp >= "2014-01-01T00:00:00Z"^^xsd:dateTime) .

FILTER (?submissionTimestamp < "2015-01-01T00:00:00Z"^^xsd:dateTime) .

}

GROUP BY ?buyer

ORDER BY DESC (?totalAmount)

LIMIT 10

Αποτελέσματα ερωτήματος

|  |  |  |
| --- | --- | --- |
| **Φορέας** | **Συνολικό Ποσό** | **Αριθμός Πληρωμών** |
| http://linkedeconomy.org/resource/Organization/090208606/99206226 | 424498395726.017578 | 44 |
| http://linkedeconomy.org/resource/Organization/998396742/6009 | 9411353605.099609 | 38 |
| http://linkedeconomy.org/resource/Organization/997947640/6166 | 2423224295.69316101 | 306 |
| http://linkedeconomy.org/resource/Organization/997970170/53182 | 2200122644.17919158 | 27 |
| http://linkedeconomy.org/resource/Organization/800231941 | 2128756493.125488 | 213 |
| http://linkedeconomy.org/resource/Organization/997766391 | 1886575288.1375501 | 373 |
| http://linkedeconomy.org/resource/Organization/090003373/99219667 | 1262723729.8250179 | 1798 |
| http://linkedeconomy.org/resource/Organization/800231941/6198 | 1156334142.5932922 | 245 |
| http://linkedeconomy.org/resource/Organization/997690908 | 1010146203.0228118 | 319 |
| http://linkedeconomy.org/resource/Organization/997612598 | 834055858.7565393 | 3657 |

### Ανάδοχοι ταξινομημένοι κατά συνολικό ποσό των Συμβολαίων του έτους 2014

PREFIX pc: <http://purl.org/procurement/public-contracts#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX gr: <http://purl.org/goodrelations/v1#>

SELECT ?seller (SUM(xsd:decimal(?amount)) AS ?paymentAmount) (COUNT(?contract) AS ?contractCounter)

FROM <http://linkedeconomy.org/EprocurementProper>

WHERE {

?contract pc:agreedPrice ?ups ;

elod:seller ?seller ;

elod:submissionTimestamp ?submissionTimestamp .

?ups gr:hasCurrencyValue ?amount .

FILTER NOT EXISTS {?correctedDec elod:hasCorrectedDecision ?contract } .

FILTER (?submissionTimestamp >= "2014-01-01T00:00:00Z"^^xsd:dateTime) .

FILTER (?submissionTimestamp < "2015-01-01T00:00:00Z"^^xsd:dateTime) .

}

GROUP BY ?seller

ORDER BY DESC (?paymentAmount)

LIMIT 10

Αποτελέσματα ερωτήματος

|  |  |  |
| --- | --- | --- |
| **Ανάδοχος** | **Συνολικό**  **Ποσό** | **Αριθμός Συμβολαίων** |
| http://linkedeconomy.org/resource/Organization/070671151 | 3136200571.0625 | 2 |
| http://linkedeconomy.org/resource/Organization/094006030 | 112355051.5625 | 5 |
| http://linkedeconomy.org/resource/Organization/997432483 | 90774000 | 2 |
| http://linkedeconomy.org/resource/Organization/999664695 | 57529872 | 2 |
| http://linkedeconomy.org/resource/Organization/099755631 | 54614192 | 1 |
| http://linkedeconomy.org/resource/Organization/997921985 | 49084980 | 2 |
| http://linkedeconomy.org/resource/Organization/094026421 | 46511894.59716 | 121 |
| http://linkedeconomy.org/resource/Organization/094419505 | 39326122 | 2 |
| http://linkedeconomy.org/resource/Organization/094432748 | 35968472 | 3 |
| http://linkedeconomy.org/resource/Organization/094180805 | 27087977.223632 | 9 |

# Συνδυασμός Πηγών

Η οντολογία προκύπτει από τη συνένωση των οντολογικών σχημάτων που περιγράφηκαν για τις παρακάτω πηγές: Διαύγεια, ΚΗΜΔΗΣ, ΕΣΠΑ και ΧΑΑ. Οι περιγραφή των κλάσεων και των ιδιοτήτων μπορούν να βρεθούν στις αντίστοιχες υποενότητες.

## Ερωτήματα & Αποτελέσματα (SPARQL Queries)

### Ανάδοχοι με συναλλαγές στη Διαύγεια, στο ΚΗΜΔΗΣ και στο ΕΣΠΑ

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT DISTINCT ?seller

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#Diavgeia

?expAppr elod:hasExpenditureLine ?expLineExpAppr ;

rdf:type elod:ExpenseApprovalItem .

?expLineExpAppr elod:seller ?seller .

#KHMDHS

?cntr elod:seller ?seller ;

rdf:type pc:Contract .

#ESPA

?subsidy elod:beneficiary ?seller ;

rdf:type elod:Subsidy.

}

LIMIT 10

Αποτελέσματα ερωτήματος

|  |
| --- |
| **Ανάδοχος** |
| http://linkedeconomy.org/resource/Organization/082993120 |
| http://linkedeconomy.org/resource/Organization/094311705 |
| http://linkedeconomy.org/resource/Organization/102478909 |
| http://linkedeconomy.org/resource/Organization/032502798 |
| http://linkedeconomy.org/resource/Organization/101940406 |
| http://linkedeconomy.org/resource/Organization/082785679 |
| http://linkedeconomy.org/resource/Organization/082964412 |
| http://linkedeconomy.org/resource/Organization/800324752 |
| http://linkedeconomy.org/resource/Organization/094407125 |
| http://linkedeconomy.org/resource/Organization/090071277 |

### Πλήθος συναλλαγών Αναδόχου στη Διαύγεια, ΚΗΜΔΗΣ και ΕΣΠΑ

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT ?name (COUNT(DISTINCT(?expAppr)) AS ?expApprDiavgeia) (COUNT(DISTINCT(?cntr)) AS ?cntrKhmdhs) (COUNT(DISTINCT(?subsidy)) AS ?subsidyEspa)

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

FROM <http://linkedeconomy.org/Organizations>

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#Diavgeia

?expAppr elod:hasExpenditureLine ?expLineExpAppr ;

rdf:type elod:ExpenseApprovalItem .

?expLineExpAppr elod:seller <http://linkedeconomy.org/resource/Organization/800332672> .

#KHMDHS

?cntr elod:seller <http://linkedeconomy.org/resource/Organization/800332672> ;

rdf:type pc:Contract .

#ESPA

?subsidy elod:beneficiary <http://linkedeconomy.org/resource/Organization/800332672> ;

rdf:type elod:Subsidy.

#Name

<http://linkedeconomy.org/resource/Organization/800332672> gr:legalName ?name ;

gr:vatID ?vatID .

}

Αποτελέσματα ερωτήματος

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| **Ανάδοχος** | **ΑΦΜ** | **Εγκρίσεις Δαπανών** | **Συμβόλαια** | **Επιδοτήσεις** |
| FARGECO HELLAS ΣΥΛΛΟΓΗ ΕΠΕΞΕΡΓΑΣΙΑ ΑΠΟΡΡΙΜΜΑΤΩΝ ΕΤΑΙΡΕΙΑ ΠΕΡΙΟΡΙΣΜΕΝΗΣ ΕΥΘΥΝΗΣ ||FARGECO HELLAS ΕΠΕ | 800332672 | 6 | 13 | 1 |

### Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Οριστικοποίησης Πληρωμών (Β.2.2) του έτους 2015

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT ?company ?nameEn ?isin ?relatedUri (SUM(xsd:decimal(?amount)) AS ?totalAmountB22) (COUNT(DISTINCT ?payment) AS ?totalB22)

FROM <http://linkedeconomy.org/ASE>

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#Diavgeia

?payment elod:hasExpenditureLine ?expenditureLine ;

dcterms:issued ?date ;

rdf:type elod:SpendingItem .

?expenditureLine elod:seller ?relatedUri ;

elod:amount ?ups .

?ups gr:hasCurrencyValue ?amount .

FILTER (?date >= "2015-01-01T00:00:00Z"^^xsd:dateTime) .

FILTER (?date < "2016-01-01T00:00:00Z"^^xsd:dateTime) .

}

GROUP BY ?company ?nameEn ?isin ?relatedUri

ORDER BY DESC (?totalAmountB22)

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Εταιρεία** | **Όνομα** | **Κωδικός ISIN** | **Σχετιζόμενη Εταιρεία** | **Συνολικό Ποσό** | **Πλήθος Πράξεων** |
| http://linkedeconomy.org/resource/Organization/GRS434003000 | Public Power Corporation S.A. | GRS434003000 | http://linkedeconomy.org/resource/Organization/090000045 | 219446050 | 8939 |
| http://linkedeconomy.org/resource/Organization/GRS323003004 | EFG Eurobank Ergasias SA | GRS323003004 | http://linkedeconomy.org/resource/Organization/094014250 | 99599986 | 866 |
| http://linkedeconomy.org/resource/Organization/GRS414003004 | Agricultural Bank Of Greece S.A. | GRS414003004 | http://linkedeconomy.org/resource/Organization/094014298 | 74716181 | 2647 |
| http://linkedeconomy.org/resource/Organization/GRS014003008 | Piraeus Bank SA | GRS014003008 | http://linkedeconomy.org/resource/Organization/094014298 | 74716181 | 2647 |
| http://linkedeconomy.org/resource/Organization/GRS359353000 | Athens Water Supply & Sewage Co. | GRS359353000 | http://linkedeconomy.org/resource/Organization/094079101 | 35090079 | 1819 |

### Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Πληρωμών ΕΣΠΑ

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

PREFIX gr: <http://purl.org/goodrelations/v1#>

SELECT ?company ?nameEn ?isin ?relatedUri (COUNT(?subsidy) AS ?subsidyCounter) (SUM(xsd:decimal(?biAmount)) AS ?biAmount) (SUM(xsd:decimal(?cntrAmount)) AS ?cntrAmount) (SUM(xsd:decimal(?siAmount)) AS ?siAmount)

FROM <http://linkedeconomy.org/ASE>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#ESPA

?subsidy elod:hasRelatedBudgetItem ?budgetItem ;

elod:hasRelatedContract ?contract ;

elod:hasRelatedSpendingItem ?spendingItem ;

elod:beneficiary ?relatedUri .

#budgetItem

?budgetItem elod:price ?biUps .

?biUps gr:hasCurrencyValue ?biAmount .

#contract

?contract pc:agreedPrice ?cntrUps .

?cntrUps gr:hasCurrencyValue ?cntrAmount.

#spendingItem

?spendingItem elod:amount ?siUps .

?siUps gr:hasCurrencyValue ?siAmount.

}

GROUP BY ?company ?nameEn ?isin ?relatedUri

ORDER BY DESC (?siAmount)

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Όνομα Πεδίου** | **Τιμές** | | | | |
| **Εταιρεία** | http://linkedeconomy.org/resource/Organization/GRS496003005 | http://linkedeconomy.org/resource/Organization/GRS271101008 | http://linkedeconomy.org/resource/Organization/GRS221103005 | http://linkedeconomy.org/resource/Organization/GRS469003024 | http://linkedeconomy.org/resource/Organization/GRS384003000 |
| **Όνομα** | "Terna Energy S.A."@en | "Elval - Hellenic Aluminium Industry S.A."@en | "Hellenic Cables S.A."@en | "Kri-Kri S.A."@en | "Kordellos CH. Bros S.A."@en |
| **Κωδικός ISIN** | "GRS496003005" | "GRS271101008" | "GRS221103005" | "GRS469003024" | "GRS384003000" |
| **Σχετιζόμε-νη Εταιρεία** | http://linkedeconomy.org/resource/Organization/094006030 | http://linkedeconomy.org/resource/Organization/094100416 | http://linkedeconomy.org/resource/Organization/094039428 | http://linkedeconomy.org/resource/Organization/094289571 | http://linkedeconomy.org/resource/Organization/094130887 |
| **Πλήθος Επιδοτή-σεων** | 9 | 4 | 2 | 6 | 1 |
| **Ποσό Προϋπολο-γισμού** | 34109134 | 6775009 | 5860473 | 3712138 | 2687320 |
| **Ποσό Συμβο-λαίου** | 34109134 | 6775009 | 5860473 | 3712138 | 2687320 |
| **Ποσό Πληρωμής** | 20102736 | 6565140 | 4917724 | 3569338 | 2687320 |

### Στοιχεία Πληρωμής και Αντικειμένου Εισηγμένης ως Ανάδοχος στο ΚΗΜΔΗΣ

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT ?company ?nameEn ?isin ?relatedUri ?payment ?signatureDate ?buyer ?buyerLegalName ?cpvEnglishSubject ?description ?amountOfThisGood ?unitOfMeasurement ?prodLabel (xsd:decimal(?amount) AS ?amount) ?vatPercentage (xsd:decimal((1+?vatPercentage/100)\*?amount) AS ?amountInclVat)

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://publicspending.net/DiavgeiaI/CPV>

FROM <http://linkedeconomy.org/Organizations>

FROM <http://linkedeconomy.org/ASE>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#KHMDHS

?payment elod:buyer ?buyer ;

pc:item ?offering ;

elod:signatureDate ?signatureDate .

#offering

?offering gr:includesObject ?tqn ;

gr:hasPriceSpecification ?ups ;

elod:seller ?relatedUri .

#tqn

?tqn gr:typeOfGood ?someItems ;

gr:amountOfThisGood ?amountOfThisGood ;

gr:hasUnitOfMeasurement ?unitOfMeasurement .

#ups

?ups elod:hasVat ?vat ;

gr:hasCurrencyValue ?amount .

#someItems

?someItems elod:productCategory ?cpv ;

gr:description ?description ;

elod:producedAt ?producedAt .

?buyer gr:legalName ?buyerLegalName .

?vat elod:vatPercentage ?vatPercentage .

?cpv elod:cpvEnglishSubject ?cpvEnglishSubject .

?producedAt skos:prefLabel ?prodLabel .

FILTER(LANGMATCHES(LANG(?prodLabel), "el")) .

FILTER NOT EXISTS {?payment elod:hasCorrectedDecision ?correctedDec } .

}

ORDER BY DESC (?amountInclVat)

LIMIT 1

Αποτελέσματα ερωτήματος

|  |  |
| --- | --- |
| **Όνομα Πεδίου** | **Τιμή** |
| **URI** | http://linkedeconomy.org/resource/Organization/GRS432003010 |
| **Όνομα** | "Intracom Constructions S.A.TECHN & Steel CONSTR."@en |
| **Κωδικός ISIN** | "GRS432003010" |
| **Σχετιζόμενο URI** | <http://linkedeconomy.org/resource/Organization/094207780> |
| **Πληρωμή** | <http://linkedeconomy.org/resource/Contract/13PAY001776162> |
| **Ημ/νια Υπογραφής** | 2013-12-11+03:00 |
| **Φορέας** | <http://linkedeconomy.org/resource/Organization/997612598> |
| **Όνομα Φορέα** | "ΠΕΡΙΦΕΡΕΙΑ ΚΕΝΤΡΙΚΗΣ ΜΑΚΕΔΟΝΙΑΣ"@el |
| **Περιγραφή CPV** | "Road construction works" |
| **Περιγραφή Πληρωμής** | Κατασκευή οδικού τμήματος Ποτίδαια- Κασσανδρεία του οδικού κυκλώματος Κασσάνδρας Ν. Χαλκιδικής (Υπογράφων σύμβασης Μπέκας Παύλος Δ/ντης ΔΕΚΕ ΠΚΜ) |
| **Ποσότητα** | 1.0 |
| **Μονάδα Μέτρησης** | Service |
| **Χώρα Προέλευσης** | "Ελλάδα"@el |
| **Ποσό (χωρίς ΦΠΑ)** | 41920968 |
| **ΦΠΑ** | 23.0 |
| **Ποσό (με ΦΠΑ)** | 51562791.43 |